Wave packets

Previous Lecture

prob[z_]:=Simplify[ComplexExpand[Conjugate[z]]*z]

ϕraw= ((2 C0 ℏ)/x) Exp[  I  p0 x/ℏ] Sin[ ((Δp x)/(2ℏ))]

p=prob[ϕraw]

normIntegral =Integrate[p,{x,-Infinity,Infinity},GenerateConditions-> False]//PowerExpand

ϕ=ϕraw/. C0->  (1/(Sqrt[2 π Δp ℏ ]))

ϕ=PowerExpand[ϕ]

ϕstar=ExpToTrig[ϕ]/. {I-> -I};

ϕstarϕ=Simplify[(ϕstar ϕ)]

probTemp=Simplify[(ϕstar ϕ)/.{ x -> s (ℏ/(Δp))}]

Plot[(ℏ/(Δp))probTemp ,{s,-16,16},Frame-> True,FrameLabel-> {"x /(ℏ/(Δp))","((Δp)/ℏ)|ϕ((|)^2)"},BaseStyle->{FontWeight->"Plain",FontSize->24}]

Your text wants to discuss Δx.  By definition Δx = (Sqrt[<(x^2)> - <x((>)^2)]).   By symmetry it is “obvious” that at t=0, <x>=0.  But...

Integrate[(x^2) ϕstarϕ,{x,-Infinity,Infinity}]

Oops!  That’s the problem with working with an infinite interval - it’s hard to deal with infinite plane waves.  Your textbook defines the uncertainty in x as the distance between the zeroes in the above plot.  In our units Δs=4π.  Then

		Δx Δp = (4π) (ℏ/(Δp))Δp=2 h

Gaussian wavepackets

ϕraw= Exp[I p0 x /ℏ]  Exp[((-(x^2))/(a^2))]

integrand=prob[ϕraw]

cval=Integrate[integrand,{x,-Infinity,Infinity},GenerateConditions-> False]//PowerExpand

ϕ=(1/(Sqrt[cval]))ϕraw

avgx=Integrate[x prob[ϕ],{x,-Infinity,Infinity},GenerateConditions-> False]//PowerExpand

avgx2=Integrate[(x^2)prob[ϕ],{x,-Infinity,Infinity},GenerateConditions-> False]//PowerExpand

integrand= (ℏ/I)(-((2 x)/(a^2))+((I p0)/ℏ)) prob[ϕ]//FullSimplify

avgp=Integrate[integrand,{x,-Infinity,Infinity},GenerateConditions-> False]//PowerExpand

integrand=-(ℏ^2)((( (-((2 x)/(a^2))+((I p0)/ℏ))))^2) prob[ϕ]//FullSimplify

avgp2=Integrate[integrand,{x,-Infinity,Infinity},GenerateConditions-> False]//PowerExpand

FullSimplify[(avgp2-(avgp^2))/.Arg[a]-> 0]

Square Well Expansions

Square packet in a square well

width=.3;
initCond=UnitStep[x-(1/2-(width/2))]-UnitStep[x-(1/2+(width/2))];
Plot[initCond,{x,0,1},AspectRatio-> .2,PlotRange-> {0,1}]

sqval=N[Simplify[FullSimplify[PowerExpand[Integrate[initCond Sin[n π x] ,{x,0,1}]]]]];

nmax=40;
fxnList=Chop[Total[Table[2sqval Sin[n π x],{n,1,nmax}]]];
Plot[Re[fxnList],{x,0,1},AspectRatio-> .2,PlotRange-> Automatic]

Manipulate[
fxnList=Chop[Total[Table[2sqval Sin[n π x],{n,1,varmax}]]];
Plot[((Abs[fxnList])^2),{x,0,1},AspectRatio-> .2,PlotRange-> {0,1.5}],{varmax,5,100,5}]

Gaussian packet in a square well

width=.1;
initCond=Exp[-(((((x-1/2)/(width/2))))^2)];
aval=N[Simplify[FullSimplify[PowerExpand[Integrate[initCond Sin[n π x] ,{x,0,1}]]]]];

nmax=40;
fxnList=Chop[Total[Table[2aval Sin[n π x],{n,1,nmax}]]];
Plot[Re[fxnList],{x,0,1},AspectRatio-> .2,PlotRange-> {0,1}]

Manipulate[
fxnList=Chop[Total[Table[2aval Sin[n π x],{n,1,varmax}]]];
Plot[((Abs[fxnList])^2),{x,0,1},AspectRatio-> .2,PlotRange-> {0,1}],{varmax,2,40,2}]

Manipulate[
fxnList2=Chop[Total[Table[2aval Sin[n π x] Exp[-I (n^2) t],{n,1,40}]]];
Plot[((Abs[fxnList2])^2),{x,0,1},AspectRatio-> .2,PlotRange-> {0,1}],{t,0,.1,.001}]

Time Evolutions

Matter Waves

width=.1;
pval=40.;
initCond3=Exp[-(((((x-1/2)/(width/2))))^2)+ I pval x];
aval=N[Simplify[FullSimplify[PowerExpand[Integrate[initCond3 Sin[n π x] ,{x,0,1}]]]]];

Manipulate[
fxnList3=Chop[Total[Table[2aval Sin[n π x] Exp[-I (n^2) t],{n,1,40}]]];
Plot[{Re[fxnList3],((Abs[fxnList3])^2)},{x,0,1},AspectRatio-> .2,PlotRange-> {-1,1},PlotLabel-> "Evolution of Matter Wave"],{t,0,.2,.002}]

Here’s how the square packet evolves:

width=.3;
pval=80;
initCond=Exp[ I pval x ](UnitStep[x-(1/2-(width/2))]-UnitStep[x-(1/2+(width/2))]);
bval=N[Simplify[FullSimplify[PowerExpand[Integrate[initCond Sin[n π x] ,{x,0,1}]]]]];
Manipulate[
fxnList5=Chop[Total[Table[2bval Sin[n π x] Exp[-I (n^2) t],{n,1,60}]]];
Plot[{Re[fxnList5],((Abs[fxnList5])^2)},{x,0,1},AspectRatio-> .2,PlotRange-> {-1.5,1.5},PlotLabel-> "Evolution of Matter Wave"],{t,0,.1,.001}]

Light waves

Manipulate[
fxnList4=Chop[Total[Table[2aval Sin[n π x] Exp[-I n t],{n,1,40}]]];
Plot[{Re[fxnList4],((Abs[fxnList4])^2)},{x,0,1},AspectRatio-> .2,PlotRange-> {-1,1},PlotLabel-> "Evolution of Light Wave"],{t,0,.4,.01}]

Manipulate[
fxnList4=Chop[Total[Table[2aval Sin[n π x] Exp[-I (Sqrt[((n^2) +100)])t],{n,1,40}]]];
Plot[Re[fxnList4],{x,0,1},AspectRatio-> .2,PlotRange-> {-1,1},PlotLabel-> "Evolution of Meson Wave"],{t,0,1,.01}]